Delphi: отладка, запись в лог

Давненько не писала про Delphi, а ведь именно в Delphi провожу большую часть дня :) Итак, сегодня расскажу о том, как я пишу логи.

Запись в лог я использую во всех более-менее серьезных проектах. Логирование помогает и на этапе отладки, и на этапе внедрения (иногда проще попросить прислать лог, чем со слов понять, в чем проблема). Давно уже использую для этих целей маленькую и удобную библиотечку uLog. Все, что от вас потребуется, это добавить ее в uses. Ну и по желанию некоторые настройки. Но даже уже без всяких настроек вы можете писать в лог с помощью процедуры sLog. Пример:

sLog ('MyProgram.log','Значение переменной ='+str);

Первый входной параметр — куда писать, второй — что писать. Если путь прописан не полностью — идет обращение к текущей директории проекта. Если файл не существует - он будет создан автоматически. В логе строчки появляются снабженные временем записи в лог. Пример части лога:

07.07.2010 16:34:11 [243] Starting...
07.07.2010 16:34:11 [243] Signature:A951D217D6B5E340 03040002 940000000500000001000000280A00000200000053657276696365205061636B2032000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000
07.07.2010 16:34:11 [243] LoadConf...

(в квадратных скобках после времени - миллисекунды)

Немного о настройках. Первое, что можно настраивать, - это файл по умолчанию, в который будет писаться лог. Для этого обращаемся к uLog.LogFileName.
Пример:

uLog.LogFileName := ExtractFilePath(GetModuleName(HInstance))+'TaskManager.log';

После установки LogFileName лог будет писаться в указанный файл, если первый входной параметр у sLog не будет задан:

sLog('','Инициализация прошла успешно');

Еще один параметр - EnableMessages. Он отвечает за то, будут ли появляться сообщения об ошибке в этой библиотеке (например, когда файл лога не указан и не задан по умолчанию).

uLog.EnableMessages := false;

И, наконец, самый замечательный параметр. Он передается в sLog третьим. Это "уровень логирования", LogLevel.

slog('','Starting library',2);
slog('',tmpS,3);

Вы сами проставляете этот уровень в зависимости от того, что за информацию пишете в лог. Градация, например, может быть такой:

1. мегаважный


2. информационный (запустился, ...)


3. отладочный

Уровней может быть больше, сколько угодно. При приведенном в предыдущем абзаце варианте вы на этапе разработки используете LogLevel := 3, а когда устанавливаете продукт клиенту, ставите LogLevel 1 или 2. LogLevel удобно задавать в ini-файле и считывать при запуске приложения. Если вдруг у клиента внезапно начнутся какие-то сбои - под вашим руководством он сможет поменять уровень логирования на 3 и прислать вам файл с отладочной информацией, которая поможет вам выяснить причину сбоев.

Листинг этой чудесной библиотечки:

unit uLog;

interface
  procedure sLog (aLogFileName: String; aMessage : String;
                  aLevel : integer = 1 ;
                  aRewrite : boolean = false ;
                  aIncludeDateTime : boolean=true   ) ;
  var
    LogLevel : integer = 3 ;
    EnableMessages : boolean = true ;
    LogFileName : String ;
    // 1 - мегаважный
    // 2 - информационный (запустился, ...)
    // 3 - отладочный

implementation

uses SysUtils, Dialogs, DateUtils;

procedure sLog (aLogFileName: String; aMessage : String;
                  aLevel : integer = 1 ;
                  aRewrite : boolean = false ;
                  aIncludeDateTime : boolean=true   ) ;
  var
   Y,M,D,H,Min,Sec,MSec : word ;
   LF : Text ;
   S : String ;
   S1 : String ;
   N : TDateTime ;
  begin
   {$I-}
   if aLogFileName='' then aLogFileName:=LogFileName ;
   if aLevel<= LogLevel then
    begin
     S:='' ;
     AssignFile(LF,aLogFileName) ;
     if FileExists(aLogFileName) then
      begin
       if aRewrite then Rewrite(LF) else append(LF) ;
       if IOResult<>0 then
        if EnableMessages then
          ShowMessage('error appending message ' + aMessage) ;
      end
     else
      begin
       rewrite(LF) ;
      if IOResult<>0 then
       if EnableMessages then
        ShowMessage('error rewriting message ' + aMessage) ;
      end ;
     if aIncludeDateTime then
      begin
       N:=Now ;
       DecodeDateTime(N,Y,M,D,H,Min,Sec,MSec);
       S1:=' [' + IntToStr(MSec)+ '] ' ;
       while Length(S1) <7 do S1:=S1+' ' ;
       S:=DateTimeToStr(N) + S1 ;
      end;
     S:=S + aMessage ;
     writeln(LF,S) ;
     if IOResult<>0 then
      if EnableMessages then
       ShowMessage('error writing message ' + aMessage) ;
     closeFile(LF) ;
     if IOResult<>0 then
      if EnableMessages then ShowMessage('error closing message ' + aMessage) ;
    end ;
   {$I+}
  end ;

end.

___

Добавлю ссылку на класс, который написал Егор. С помощью класса можно посмотреть дамп любой области памяти и актуальный стекфлоу. Спасибо ему большое!
___

Чтобы быть в курсе обновлений блога, можно подписаться на RSS.

Статьи схожей тематики: